build.gradle

plugins {
    id 'java-library'
    id 'idea'
    id 'maven-publish'
    id 'net.neoforged.gradle.userdev' version '7.0.154'
    id "me.modmuss50.mod-publish-plugin" version "0.4.5"
}
apply from: 'https://files.saps.dev/ci/git-md-changelog.gradle'

def ENV = System.getenv()
version = "${mod_version}+mc${minecraft_version}-b${ENV.GITHUB_RUN_NUMBER ?: 9999}"
group = 'com.flanks255'
base {
    archivesName = 'simplygraves'
}

java.toolchain.languageVersion = JavaLanguageVersion.of(21)

//minecraft.accessTransformers.file rootProject.file('src/main/resources/META-INF/accesstransformer.cfg') //The file is empty, so this is commented out

runs {
    // applies to all the run configs below
    configureEach {
        //Limit ram usage for the dev environment to 4GB
        jvmArgument '-Xmx8G'

        modSource project.sourceSets.main
    }

    client {
        // Comma-separated list of namespaces to load gametests from. Empty = all namespaces.
        systemProperty 'neoforge.enabledGameTestNamespaces', "simplygraves"
        programArguments.addAll('--width', '1280', '--height', '720')
    }

    server {
        systemProperty 'neoforge.enabledGameTestNamespaces', "simplygraves"
        programArgument '--nogui'
    }

    gameTestServer {
        systemProperty 'forge.enabledGameTestNamespaces', "simplygraves"
    }

    data {
        programArguments.addAll '--mod', "simplygraves", '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
    }
}

// Include resources generated by data generators.
sourceSets.main.resources { srcDir 'src/generated/resources' }

repositories {
    maven { url = 'https://maven.creeperhost.net/' }
    maven { url "https://www.cursemaven.com" }
}

dependencies {
    implementation "net.neoforged:neoforge:$neo_version"

    compileOnly "mezz.jei:jei-${minecraft_version}-common-api:${jei_version}" //new
    compileOnly "mezz.jei:jei-${minecraft_version}-neoforge-api:${jei_version}"
    runtimeOnly "mezz.jei:jei-${minecraft_version}-neoforge:${jei_version}"

    runtimeOnly "curse.maven:JADE-324717:5493270"
//    compileOnly "curse.maven:TOP-245211:4629624"
}

jar {
    manifest {
        attributes([
                "Specification-Title"     : "simplygraves",
                "Specification-Vendor"    : "Flanks255",
                "Specification-Version"   : "1",
                "Implementation-Title"    : project.name,
                "Implementation-Version"  : "${version}",
                "Implementation-Vendor"   : "Flanks255",
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
        ])
    }
}

publishing {
    publications {
        register('mavenJava', MavenPublication) {
            groupId project.group
            artifactId base.archivesName.get()
            version project.version
            from components.java
        }
    }

    repositories {
        if (ENV.SAPS_TOKEN) {
            maven {
                url "https://maven.saps.dev/minecraft"
                credentials {
                    username = "flanks"
                    password = "${ENV.SAPS_TOKEN}"
                }
            }
        }
    }
}

//https://modmuss50.github.io/mod-publish-plugin/
publishMods {
    dryRun = !providers.environmentVariable("CURSEFORGE_KEY").isPresent()
    file = jar.archiveFile
    changelog = file("./CHANGELOG.md").text
    modLoaders.add("NeoForge")
    type = BETA
    curseforge {
        accessToken = providers.environmentVariable("CURSEFORGE_KEY")
        projectId = project.curseforge_id
        minecraftVersions.add(project.minecraft_version)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}