build.gradle

import java.time.Instant

plugins {
	id 'base'
	id 'java'
	id 'maven-publish'
	id "dev.architectury.loom" version "1.6-SNAPSHOT"
	id "me.shedaniel.unified-publishing" version "0.1.+"
}

ext.ENV = System.getenv()

repositories {
	mavenCentral()

	maven {
		url "https://maven.architectury.dev/"
	}

	maven {
		url "https://maven.latvian.dev/releases"
		content {
			includeGroup "dev.latvian.mods"
		}
	}

	mavenLocal()
}

def isLocal = !ENV.containsKey("GITHUB_RUN_NUMBER")

version = "${mod_version}-${isLocal ? "local.${Instant.now().epochSecond}" : "build.${ENV.GITHUB_RUN_NUMBER}"}"
group = project.maven_group
base.archivesBaseName = project.archives_base_name

loom {
	silentMojangMappingsLicense()

	interfaceInjection {
		interfaceInjectionSourceSets.add sourceSets.main
	}

	runs {
		client {
			if (ENV.MC_CLIENT_ARGS) {
				programArgs ENV.MC_CLIENT_ARGS.split(' ')
			}

			vmArgs("-XX:+IgnoreUnrecognizedVMOptions", "-XX:+AllowEnhancedClassRedefinition")
			runDir = 'run'
		}

		server {
			runDir = 'run_server'
		}
	}
}

compileJava {
	options.encoding = "UTF-8"
	options.release.set(21)
}

java {
	sourceCompatibility = targetCompatibility = '21'
	withSourcesJar()
}

repositories {
	mavenLocal()
	mavenCentral()

	maven {
		url "https://maven.architectury.dev/"
	}

	maven {
		url "https://maven.latvian.dev/releases"
		content {
			includeGroup "dev.latvian.mods"
		}
	}

	maven {
		url "https://maven.neoforged.net/releases"
	}
}

dependencies {
	minecraft "com.mojang:minecraft:$minecraft_version"
	mappings loom.officialMojangMappings()

	neoForge("net.neoforged:neoforge:$neoforge_version")

	// Unit Testing
	testImplementation "org.junit.jupiter:junit-jupiter-api:$junit_version"
	testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:$junit_version"
}

test {
	useJUnitPlatform()
}

tasks {
	processResources {
		def toReplace = [
				"version": project.version
		]

		println("[Process Resources] Replacing properties in resources: " + toReplace)

		inputs.properties toReplace
		filesMatching("META-INF/neoforge.mods.toml") {
			expand toReplace
		}

		filesMatching("fabric.mod.json") {
			expand toReplace
		}
	}
}

jar {
	manifest {
		attributes([
				"Specification-Title"     : project.mod_id,
				"Specification-Vendor"    : project.mod_author,
				"Specification-Version"   : "1",
				"Implementation-Title"    : project.name,
				"Implementation-Version"  : version,
				"Implementation-Vendor"   : project.mod_author,
				"Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
		])
	}
}

unifiedPublishing {
	project {
		releaseType = "${ENV.RELEASE_TYPE ?: 'release'}"
		gameVersions = Arrays.asList(rootProject.supported_versions.split(', '))
		gameLoaders = ["neoforge", "forge", "fabric"]
		displayName = "$mod_name $project.version"
		changelog = 'Changelog not available'
		mainPublication remapJar

		if (ENV.CURSEFORGE_KEY) {
			curseforge {
				token = ENV.CURSEFORGE_KEY
				id = project.curseforge_id
			}
		}

		if (ENV.MODRINTH_TOKEN) {
			modrinth {
				token = ENV.MODRINTH_TOKEN
				id = project.modrinth_id
				version = "$project.version+$project.name"
			}
		}
	}
}

publishing {
	publications {
		mavenNeoForge(MavenPublication) {
			artifactId = "${rootProject.archives_base_name}"
			from components.java
		}
	}

	repositories {
		if (ENV.MAVEN_TOKEN) {
			maven {
				url "https://maven.latvian.dev/releases"
				credentials {
					username = "lat"
					password = "${ENV.MAVEN_TOKEN}"
				}
			}
		}

		if (ENV.SAPS_TOKEN) {
			maven {
				url "https://maven.saps.dev/releases"
				credentials {
					username = "latvian"
					password = "${ENV.SAPS_TOKEN}"
				}
			}
		}
	}
}