firewall-whitelisting-failcount

#!/usr/bin/env perl

# clear failed user login attempt counter
# by Jon Jensen <jon@endpointdev.com>
# March 2007

=for comment

This program is free software: you can redistribute it and/or modify it
under the terms of the GNU General Public License as published by the
Free Software Foundation, either version 3 of the License, or (at your
option) any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
Public License for more details.

You should have received a copy of the GNU General Public License along
with this program. If not, see <https://www.gnu.org/licenses/>.

=cut

use warnings;
use strict;
use DB_File;
use Getopt::Std;
use IO::Handle;

*STDOUT->autoflush(1);
*STDERR->autoflush(1);

my $user_attempts_file = '/var/log/httpd/firewall.users.failed.attempts';

my %opts;
getopts('lzdh?', \%opts);

tie my %user_attempts, 'DB_File', $user_attempts_file
	or die "Error tie-ing $user_attempts_file\n";

my @users = @ARGV;

if ($opts{h} or $opts{'?'} or ! %opts) {
	print STDERR <<'END';
Usage: firewall.failcount [-l] [-z] [-d] [user] [user...]

-l list counter
-z zero user counter
-d delete user entry

If no users are specified, act on all users.
END
	exit 1;
}

@users = sort keys %user_attempts unless @users;

for my $user (@users) {
	my $count = $user_attempts{$user};
	print "$user: ";
	if (! defined $count) {
		print "no counter\n";
	}
	else {
		print $count;
		if ($opts{d}) {
			delete $user_attempts{$user};
			print ' - deleted';
		}
		elsif ($opts{z} and $count) {
			$user_attempts{$user} = 0;
			print ' - reset to 0';
		}
		print "\n";
	}
}

untie %user_attempts
	or die "Error untie-ing file $user_attempts_file!\n";