build.gradle

apply plugin: 'idea'

version = '1.0.0'
def jarVersion = version

buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }

    dependencies {
        classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.5.0'
    }
}

allprojects {
    repositories {
        mavenLocal()
        mavenCentral()
    }

    gradle.projectsEvaluated {
        tasks.withType(JavaCompile) {
            options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
        }
    }

    apply plugin: 'jacoco'
    apply plugin: 'com.github.kt3k.coveralls'
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'eclipse'
    apply plugin: 'idea'

    group = 'org.cf'
    sourceCompatibility = 1.8
    version = parent.version

    jar {
        version = jarVersion
    }

    ext {
        depends = [
            commons_lang: 'org.apache.commons:commons-lang3:3.4',
            findbugs: 'com.google.code.findbugs:jsr305:3.0.1',
            guava: 'com.google.guava:guava:19.0',
            junit: 'junit:junit:4.12',
            mockito: 'org.mockito:mockito-core:1.10.19',
            perfidix: 'org.perfidix:perfidix:3.6.9',
            proguard_gradle: 'net.sf.proguard:proguard-gradle:5.2.1',
            slf4j_api: 'org.slf4j:slf4j-api:1.7.16',
            trove4j: 'net.sf.trove4j:trove4j:3.0.3',
         ]
    }

    // This is just to show off API usage. No tests needed.
    if (!project.name.equals("demoapp")) {
        jacocoTestReport {
            reports {
                html.enabled = true
                xml.enabled = true
                csv.enabled = false
            }
        }
    }
}

coveralls {
    sourceDirs = files(subprojects.sourceSets.main.allSource.srcDirs).files.absolutePath
}

task jacocoTestReport(type: org.gradle.testing.jacoco.tasks.JacocoReport) {
    ext.targetProjects = subprojects - project(':demoapp')

    dependsOn = ext.targetProjects.test
    sourceDirectories = files(ext.targetProjects.sourceSets.main.allSource.srcDirs)
    classDirectories = files(ext.targetProjects.sourceSets.main.output)
    executionData = files(ext.targetProjects.jacocoTestReport.executionData)

    reports {
        html.enabled = true
        xml.enabled = true
        csv.enabled = false
    }

    onlyIf = {
        true
    }

    doFirst {
        executionData = files(executionData.findAll {
            it.exists()
        })
    }
}