Added: QTE Framework

addons/common/CfgFunctions.hpp

@@ -141,5 +141,12 @@ class CfgFunctions {
         class Broken {
             PATHTO_FNC(actionArgument);
         };
+
+        class QuickTimeEvent {
+            PATHTO_FNC(generateQTESequence);
+            PATHTO_FNC(getFormattedQTESequence);
+            PATHTO_FNC(runQTE);
+            PATHTO_FNC(keyPressedQTE);
+        };
     };
 };

addons/common/XEH_preInit.sqf

@@ -1,5 +1,6 @@
 //#define DEBUG_MODE_FULL
 #include "script_component.hpp"
+#include "\a3\ui_f\hpp\defineDIKCodes.inc"
 SCRIPT(XEH_preInit);
 
 LOG(MSG_INIT);
@@ -78,3 +79,19 @@ activateAddons GVAR(addons);
 ["CAManBase", "InitPost", CBA_fnc_randomizeFacewear] call CBA_fnc_addClassEventHandler;
 
 ADDON = true;
+
+[ELSTRING(QTEKeybindGroup), "QTE_Up_Key", ["↑", LSTRING(QTEKeybindUpTooltip)], {}, {
+    ["↑"] call CBA_fnc_keyPressedQTE;
+}, [DIK_UP, [false, true, false]]] call CBA_fnc_addKeybind;
+
+[ELSTRING(QTEKeybindGroup), "QTE_Down_Key", ["↓", LSTRING(QTEKeybindDownTooltip)], {}, {
+    ["↓"] call CBA_fnc_keyPressedQTE;
+}, [DIK_DOWN, [false, true, false]]] call CBA_fnc_addKeybind;
+
+[ELSTRING(QTEKeybindGroup), "QTE_Left_Key", ["←", LSTRING(QTEKeybindLeftTooltip)], {}, {
+    ["←"] call CBA_fnc_keyPressedQTE;
+}, [DIK_LEFT, [false, true, false]]] call CBA_fnc_addKeybind;
+
+[ELSTRING(QTEKeybindGroup), "QTE_Right_Key", ["→", LSTRING(QTEKeybindRightTooltip)], {}, {
+    ["→"] call CBA_fnc_keyPressedQTE;
+}, [DIK_RIGHT, [false, true, false]]] call CBA_fnc_addKeybind;

addons/common/fnc_generateQTESequence.sqf

@@ -0,0 +1,32 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_generateQTESequence
+
+Description:
+	Generate a Quick-Time sequence of a given length.
+
+Parameters:
+    _length - <NUMBER>
+
+
+Example:
+    [5] call CBA_fnc_generateQTESequence;
+
+Returns:
+    Quick-Time sequence of requested length made up of ["↑", "↓", "→", "←"] <ARRAY>
+
+Author:
+    john681611
+---------------------------------------------------------------------------- */
+
+params [["_length", 0, [0]]];
+
+if (_length <= 0) exitWith {[]};
+
+private _code = [];
+
+for "_i" from 0 to _length do {
+    _code pushBack (selectRandom ["↑", "↓", "→", "←"]);
+};
+
+_code

addons/common/fnc_getFormattedQTESequence.sqf

@@ -0,0 +1,24 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_getFormattedQTESequence
+
+Description:
+	Formats Quick-Time sequence into a displayable string.
+
+Parameters:
+    _code - Quick-Time sequence <ARRAY>
+
+
+Example:
+    [["↑", "↓", "→", "←"]] call CBA_fnc_getFormattedQTESequence;
+
+Returns:
+    Formatted Quick-Time sequence <STRING>
+
+Author:
+    john681611
+---------------------------------------------------------------------------- */
+
+params ["_code"];
+
+_code joinString "     " // Arma doesn't know how to space ↑ so we need loads of spaces between

addons/common/fnc_keyPressedQTE.sqf

@@ -0,0 +1,62 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_keyPressedQTE
+
+Description:
+	Process Quick-Time Key Press
+
+Parameters:
+    _eventQTE - <STRING>
+
+
+Example:
+    ["↑"] call CBA_fnc_keyPressedQTE;
+
+Returns:
+    Nil
+
+Author:
+    john681611
+---------------------------------------------------------------------------- */
+
+
+params ["_eventQTE"];
+GVAR(QTERunning) = RETDEF(GVAR(QTERunning),false);
+if!(GVAR(QTERunning)) exitWith {};
+if!(_eventQTE in ["↑", "↓", "→", "←"]) exitWith {};
+
+
+private _object = GVAR(QTEArgs) get "object";
+private _args = GVAR(QTEArgs) get "args";
+private _onDisplay = GVAR(QTEArgs) get "onDisplay";
+private _onFinish = GVAR(QTEArgs) get "onFinish";
+private _onFail = GVAR(QTEArgs) get "onFail";
+private _max_distance = GVAR(QTEArgs) get "max_distance";
+private _qte_sequence = GVAR(QTEArgs) get "qte_seqence";
+private _start_time = GVAR(QTEArgs) get "start_time";
+
+private _elapsedTime = CBA_missionTime - _start_time;
+
+GVAR(QTEHistory) pushBack _eventQTE;
+
+
+if (GVAR(QTEHistory) isEqualTo _qte_sequence) exitWith {
+	GVAR(QTEHistory) = [];
+	GVAR(QTERunning) = false;
+	TRACE_1("QTE Completed",_elapsedTime);
+	if (_onFinish isEqualType "") then {
+		[_onFinish, [_args, _elapsedTime]] call CBA_fnc_localEvent;
+	} else {
+		[_args, _elapsedTime] call _onFinish;
+	};
+};
+
+if !(GVAR(QTEHistory) isEqualTo (_qte_sequence select [0, count GVAR(QTEHistory)])) then {
+	GVAR(QTEHistory) = [];
+};
+
+if (_onDisplay isEqualType "") then {
+	[_onDisplay, 	[_args, _qte_sequence,  GVAR(QTEHistory)]] call CBA_fnc_localEvent;
+} else {
+	[_args, _qte_sequence,  GVAR(QTEHistory)] call _onDisplay;
+};

addons/common/fnc_runQTE.sqf

@@ -0,0 +1,97 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_runQTE
+
+Description:
+	Runs a Quick time Event.
+
+Parameters:
+	_object - <OBJECT>
+	_args - Extra arguments passed to the _on... functions<ARRAY>
+ 	_onDisplay - Code callback on displayable event passed [_args, _qte_sequence, _qte_history]. <CODE, STRING>
+	_onFinish - Code callback on Quick-Time Event completed passed [_args, _elapsedTime]. <CODE, STRING>
+	_onFinish - Code callback on Quick-Time Event timeout/outranged passed [_args, _elapsedTime]. <CODE, STRING>
+ 	_qte_sequence - Quick-Time sequence made up of ["↑", "↓", "→", "←"] <ARRAY>
+ 	_max_distance - max interaction distance from attached object <NUMBER> (default: 10) 
+ 	_timeout - ingame timeout <NUMBER> (default: 30)
+
+Example:
+    [car,
+	[], 
+	{ 
+	hint format [
+		"%1 \n %2",
+		[_this select 1] call CBA_fnc_getFormattedQTESequence,
+		[_this select 2] call CBA_fnc_getFormattedQTESequence
+		]
+	}, 
+	{ 
+	hint "Finished!"; 
+	},
+	{ 
+		hint "Failure!"; 
+	},
+	["↑", "↓", "→", "←"]] call CBA_fnc_runQTE
+
+Returns:
+    Nil
+
+Author:
+    john681611
+---------------------------------------------------------------------------- */
+
+
+params ["_object", "_args", "_onDisplay", "_onFinish", "_onFail", "_qte_sequence", ["_max_distance", 10], ["_timeout", 30]];
+if (GVAR(QTERunning)) exitWith {
+	TRACE_1("QTE already running qeueing up",GVAR(QTERunning));
+	[{
+		!GVAR(QTERunning)
+	}, {
+		_this call FUNC(runQTE);
+	}, _this] call CBA_fnc_waitUntilAndExecute;
+};
+
+GVAR(QTEHistory) = [];
+GVAR(QTERunning) = true;
+private _start_time = CBA_missionTime;
+private _qteArgsArray = [
+	["object", _object],
+	["args", _args],
+	["onDisplay", _onDisplay],
+	["onFinish", _onFinish],
+	["onFail", _onFail],
+	["max_distance", _max_distance],
+	["qte_seqence", _qte_sequence],
+	["start_time", _start_time],
+	["timeout", _timeout]
+];
+GVAR(QTEArgs) = createHashMapObject [_qteArgsArray];
+
+// Setup 
+[{
+	private _timeout = GVAR(QTEArgs) get "timeout";
+	private _object = GVAR(QTEArgs) get "object";
+	private _max_distance = GVAR(QTEArgs) get "max_distance";
+	private _elapsedTime = CBA_missionTime - (GVAR(QTEArgs) get "start_time");
+
+	!GVAR(QTERunning) || player distance _object > _max_distance || _elapsedTime > _timeout;
+}, {
+	TRACE_1("QTE ended",GVAR(QTERunning));
+	if(!GVAR(QTERunning)) exitWith {};
+	GVAR(QTERunning) = false;
+	GVAR(QTEHistory) = [];
+	private _onFail = (GVAR(QTEArgs) get "onFail");
+	private _args = (GVAR(QTEArgs) get "args");
+	TRACE_1("QTE Failed",_args);
+	if (_onFail isEqualType "") then {
+		[_onFail, [_args, _elapsedTime]] call CBA_fnc_localEvent;
+	} else {
+		[_args, _elapsedTime] call _onFail;
+	};
+}, _this] call CBA_fnc_waitUntilAndExecute;
+
+if (_onDisplay isEqualType "") then {
+	[_onDisplay, [_args, _qte_sequence, []]] call CBA_fnc_localEvent;
+} else {
+	[_args, _qte_sequence, []] call _onDisplay;
+};

addons/common/stringtable.xml

@@ -43,5 +43,21 @@
             <Russian>CBA Оружие</Russian>
             <Korean>CBA 무기</Korean>
         </Key>
+        <Key ID="STR_cba_common_QTEKeybindGroup">
+            <English>CBA Quick-Time Events</English>  
+        </Key>
+        <Key ID="STR_cba_common_QTEKeybindUpTooltip">
+            <English>Up key used in Quick-Time Events.</English>  
+        </Key>
+        <Key ID="STR_cba_common_QTEKeybindDownTooltip">
+            <English>Down key used in Quick-Time Events.</English>  
+        </Key>
+        <Key ID="STR_cba_common_QTEKeybindLeftTooltip">
+            <English>Left key used in Quick-Time Events.</English>  
+        </Key>
+        <Key ID="STR_cba_common_QTEKeybindRightTooltip">
+            <English>Right key used in Quick-Time Events.</English>  
+        </Key>
+
     </Package>
 </Project>