Add recipe for nxp-wlan-sdk

sources/meta-yoe/dynamic-layers/variscite-bsp/recipes-connectivity/nxp-wlan-sdk/nxp-wlan-sdk_git.bb

@@ -0,0 +1,23 @@
+require nxp-wlan-sdk_git.inc
+
+SUMMARY = "NXP Wi-Fi SDK"
+
+inherit module-base
+
+TARGET_CC_ARCH += "${LDFLAGS}"
+
+do_compile () {
+    oe_runmake build
+}
+
+do_install () {
+    install -d ${D}${datadir}/nxp_wireless
+
+    install -m 0755 script/load ${D}${datadir}/nxp_wireless
+    install -m 0755 script/unload ${D}${datadir}/nxp_wireless
+    install -m 0644 README ${D}${datadir}/nxp_wireless
+}
+
+FILES:${PN} = "${datadir}/nxp_wireless"
+
+COMPATIBLE_MACHINE = "(imx-nxp-bsp)"

sources/meta-yoe/dynamic-layers/variscite-bsp/recipes-connectivity/nxp-wlan-sdk/nxp-wlan-sdk_git.inc

@@ -0,0 +1,15 @@
+SUMMARY = "NXP Wi-Fi SDK for module 88w8801/8987/8997/9098 and IW416/612"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://${WORKDIR}/git/LICENSE;md5=ab04ac0f249af12befccb94447c08b77"
+
+# For Kernel 5.4 and later
+SRCBRANCH = "lf-6.1.36_2.1.0"
+MRVL_SRC ?= "git://github.com/nxp-imx/mwifiex.git;protocol=https"
+SRC_URI = "${MRVL_SRC};branch=${SRCBRANCH}"
+SRCREV = "26246bf60afa613272156fa268e4ff99f5d810ae"
+
+S = "${WORKDIR}/git/mxm_wifiex/wlan_src"
+
+EXTRA_OEMAKE = "KERNELDIR=${STAGING_KERNEL_BUILDDIR}"
+
+RDEPENDS:${PN} = "wireless-tools"