feat: introduce OptimismSuperchainERC20Factory

packages/contracts-bedrock/.gas-snapshot

@@ -1,11 +1,11 @@
 GasBenchMark_L1CrossDomainMessenger:test_sendMessage_benchmark_0() (gas: 369356)
 GasBenchMark_L1CrossDomainMessenger:test_sendMessage_benchmark_1() (gas: 2967496)
-GasBenchMark_L1StandardBridge_Deposit:test_depositERC20_benchmark_0() (gas: 564483)
-GasBenchMark_L1StandardBridge_Deposit:test_depositERC20_benchmark_1() (gas: 4076526)
+GasBenchMark_L1StandardBridge_Deposit:test_depositERC20_benchmark_0() (gas: 564489)
+GasBenchMark_L1StandardBridge_Deposit:test_depositERC20_benchmark_1() (gas: 4076532)
 GasBenchMark_L1StandardBridge_Deposit:test_depositETH_benchmark_0() (gas: 466947)
 GasBenchMark_L1StandardBridge_Deposit:test_depositETH_benchmark_1() (gas: 3512629)
 GasBenchMark_L1StandardBridge_Finalize:test_finalizeETHWithdrawal_benchmark() (gas: 72624)
-GasBenchMark_L2OutputOracle:test_proposeL2Output_benchmark() (gas: 92973)
+GasBenchMark_L2OutputOracle:test_proposeL2Output_benchmark() (gas: 92970)
 GasBenchMark_OptimismPortal:test_depositTransaction_benchmark() (gas: 68433)
 GasBenchMark_OptimismPortal:test_depositTransaction_benchmark_1() (gas: 68903)
-GasBenchMark_OptimismPortal:test_proveWithdrawalTransaction_benchmark() (gas: 155618)
+GasBenchMark_OptimismPortal:test_proveWithdrawalTransaction_benchmark() (gas: 155615)

packages/contracts-bedrock/scripts/Artifacts.s.sol

@@ -152,6 +152,10 @@ abstract contract Artifacts {
             return payable(Predeploys.SCHEMA_REGISTRY);
         } else if (digest == keccak256(bytes("EAS"))) {
             return payable(Predeploys.EAS);
+        } else if (digest == keccak256(bytes("OptimismSuperchainERC20Factory"))) {
+            return payable(Predeploys.OPTIMISM_SUPERCHAIN_ERC20_FACTORY);
+        } else if (digest == keccak256(bytes("OptimismSuperchainERC20Beacon"))) {
+            return payable(Predeploys.OPTIMISM_SUPERCHAIN_ERC20_BEACON);
         }
         return payable(address(0));
     }

packages/contracts-bedrock/scripts/L2Genesis.s.sol

@@ -26,6 +26,7 @@ import { L1StandardBridge } from "src/L1/L1StandardBridge.sol";
 import { FeeVault } from "src/universal/FeeVault.sol";
 import { EIP1967Helper } from "test/mocks/EIP1967Helper.sol";
 import { Process } from "scripts/libraries/Process.sol";
+import { OptimismSuperchainERC20Beacon } from "src/L2/OptimismSuperchainERC20Beacon.sol";
 
 interface IInitializable {
     function initialize(address _addr) external;
@@ -254,6 +255,8 @@ contract L2Genesis is Deployer {
             setL2ToL2CrossDomainMessenger(); // 23
             setSuperchainWETH(); // 24
             setETHLiquidity(); // 25
+            setOptimismSuperchainERC20Factory(); // 26
+            setOptimismSuperchainERC20Beacon(); // 27
         }
     }
 
@@ -505,6 +508,31 @@ contract L2Genesis is Deployer {
         _setImplementationCode(Predeploys.SUPERCHAIN_WETH);
     }
 
+    /// @notice This predeploy is following the safety invariant #1.
+    ///         This contract has no initializer.
+    function setOptimismSuperchainERC20Factory() internal {
+        _setImplementationCode(Predeploys.OPTIMISM_SUPERCHAIN_ERC20_FACTORY);
+    }
+
+    /// @notice This predeploy is following the safety invariant #2.
+    function setOptimismSuperchainERC20Beacon() internal {
+        address superchainERC20Impl = Predeploys.OPTIMISM_SUPERCHAIN_ERC20;
+        console.log("Setting %s implementation at: %s", "OptimismSuperchainERC20", superchainERC20Impl);
+        vm.etch(superchainERC20Impl, vm.getDeployedCode("OptimismSuperchainERC20.sol:OptimismSuperchainERC20"));
+
+        OptimismSuperchainERC20Beacon beacon = new OptimismSuperchainERC20Beacon(superchainERC20Impl);
+        console.log(
+            "Setting %s implementation at: %s",
+            "OptimismSuperchainERC20Beacon",
+            Predeploys.OPTIMISM_SUPERCHAIN_ERC20_BEACON
+        );
+        vm.etch(Predeploys.OPTIMISM_SUPERCHAIN_ERC20_BEACON, address(beacon).code);
+
+        /// Reset so its not included state dump
+        vm.etch(address(beacon), "");
+        vm.resetNonce(address(beacon));
+    }
+
     /// @notice Sets all the preinstalls.
     ///         Warning: the creator-accounts of the preinstall contracts have 0 nonce values.
     ///         When performing a regular user-initiated contract-creation of a preinstall,

packages/contracts-bedrock/semver-lock.json

@@ -119,6 +119,14 @@
     "initCodeHash": "0xd49214518ea1a30a43fac09f28b2cee9be570894a500cef342762c9820a070b0",
     "sourceCodeHash": "0x6943d40010dcbd1d51dc3668d0a154fbb1568ea49ebcf3aa039d65ef6eab321b"
   },
+  "src/L2/OptimismSuperchainERC20Beacon.sol": {
+    "initCodeHash": "0x99ce8095b23c124850d866cbc144fee6cee05dbc6bb5d83acadfe00b90cf42c7",
+    "sourceCodeHash": "0x00eb41c15cf548dfb6425f317d85262c1edd5f1ad2386a6a76695781d158cf16"
+  },
+  "src/L2/OptimismSuperchainERC20Factory.sol": {
+    "initCodeHash": "0x98011045722178751e4a1112892f7d9a11bc1f5e42ac18205b6d30a1f1476d24",
+    "sourceCodeHash": "0xc64e7f9719edf94a83ac8854b6236c451b8a0fb0e998621c41f4f1c94b5e46d3"
+  },
   "src/L2/SequencerFeeVault.sol": {
     "initCodeHash": "0xb94145f571e92ee615c6fe903b6568e8aac5fe760b6b65148ffc45d2fb0f5433",
     "sourceCodeHash": "0x8f2a54104e5e7105ba03ba37e3ef9b6684a447245f0e0b787ba4cca12957b97c"

packages/contracts-bedrock/snapshots/abi/OptimismSuperchainERC20Beacon.json

@@ -0,0 +1,39 @@
+[
+  {
+    "inputs": [
+      {
+        "internalType": "address",
+        "name": "_implementation",
+        "type": "address"
+      }
+    ],
+    "stateMutability": "nonpayable",
+    "type": "constructor"
+  },
+  {
+    "inputs": [],
+    "name": "implementation",
+    "outputs": [
+      {
+        "internalType": "address",
+        "name": "",
+        "type": "address"
+      }
+    ],
+    "stateMutability": "view",
+    "type": "function"
+  },
+  {
+    "inputs": [],
+    "name": "version",
+    "outputs": [
+      {
+        "internalType": "string",
+        "name": "",
+        "type": "string"
+      }
+    ],
+    "stateMutability": "view",
+    "type": "function"
+  }
+]

packages/contracts-bedrock/snapshots/abi/OptimismSuperchainERC20Factory.json

@@ -0,0 +1,93 @@
+[
+  {
+    "inputs": [
+      {
+        "internalType": "address",
+        "name": "_remoteToken",
+        "type": "address"
+      },
+      {
+        "internalType": "string",
+        "name": "_name",
+        "type": "string"
+      },
+      {
+        "internalType": "string",
+        "name": "_symbol",
+        "type": "string"
+      },
+      {
+        "internalType": "uint8",
+        "name": "_decimals",
+        "type": "uint8"
+      }
+    ],
+    "name": "deploy",
+    "outputs": [
+      {
+        "internalType": "address",
+        "name": "_superchainERC20",
+        "type": "address"
+      }
+    ],
+    "stateMutability": "nonpayable",
+    "type": "function"
+  },
+  {
+    "inputs": [
+      {
+        "internalType": "address",
+        "name": "superchainToken",
+        "type": "address"
+      }
+    ],
+    "name": "deployments",
+    "outputs": [
+      {
+        "internalType": "address",
+        "name": "remoteToken",
+        "type": "address"
+      }
+    ],
+    "stateMutability": "view",
+    "type": "function"
+  },
+  {
+    "inputs": [],
+    "name": "version",
+    "outputs": [
+      {
+        "internalType": "string",
+        "name": "",
+        "type": "string"
+      }
+    ],
+    "stateMutability": "view",
+    "type": "function"
+  },
+  {
+    "anonymous": false,
+    "inputs": [
+      {
+        "indexed": true,
+        "internalType": "address",
+        "name": "superchainToken",
+        "type": "address"
+      },
+      {
+        "indexed": true,
+        "internalType": "address",
+        "name": "remoteToken",
+        "type": "address"
+      },
+      {
+        "indexed": false,
+        "internalType": "address",
+        "name": "deployer",
+        "type": "address"
+      }
+    ],
+    "name": "OptimismSuperchainERC20Created",
+    "type": "event"
+  }
+]

packages/contracts-bedrock/snapshots/storageLayout/OptimismSuperchainERC20Beacon.json

@@ -0,0 +1 @@
+[]

packages/contracts-bedrock/snapshots/storageLayout/OptimismSuperchainERC20Factory.json

@@ -0,0 +1,9 @@
+[
+  {
+    "bytes": "32",
+    "label": "deployments",
+    "offset": 0,
+    "slot": "0",
+    "type": "mapping(address => address)"
+  }
+]

packages/contracts-bedrock/src/L2/OptimismSuperchainERC20Beacon.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.15;
+
+import { IBeacon } from "@openzeppelin/contracts/proxy/beacon/IBeacon.sol";
+import { ISemver } from "src/universal/ISemver.sol";
+
+/// @custom:predeployed 0x4200000000000000000000000000000000000027
+/// @title OptimismSuperchainERC20Beacon
+/// @notice OptimismSuperchainERC20Beacon is the beacon proxy for the OptimismSuperchainERC20 implementation.
+contract OptimismSuperchainERC20Beacon is IBeacon, ISemver {
+    /// @notice Address of the OptimismSuperchainERC20 implementation.
+    address internal immutable IMPLEMENTATION;
+
+    /// @notice Semantic version.
+    /// @custom:semver 1.0.0-beta.1
+    string public constant version = "1.0.0-beta.1";
+
+    constructor(address _implementation) {
+        IMPLEMENTATION = _implementation;
+    }
+
+    /// @inheritdoc IBeacon
+    function implementation() external view override returns (address) {
+        return IMPLEMENTATION;
+    }
+}

packages/contracts-bedrock/src/L2/OptimismSuperchainERC20Factory.sol

@@ -0,0 +1,62 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.25;
+
+import { IOptimismERC20Factory } from "src/L2/IOptimismERC20Factory.sol";
+import { ISemver } from "src/universal/ISemver.sol";
+import { OptimismSuperchainERC20 } from "src/L2/OptimismSuperchainERC20.sol";
+import { Predeploys } from "src/libraries/Predeploys.sol";
+import { BeaconProxy } from "@openzeppelin/contracts-v5/proxy/beacon/BeaconProxy.sol";
+import { CREATE3 } from "@rari-capital/solmate/src/utils/CREATE3.sol";
+
+/// @custom:proxied
+/// @custom:predeployed 0x4200000000000000000000000000000000000026
+/// @title OptimismSuperchainERC20Factory
+/// @notice OptimismSuperchainERC20Factory is a factory contract that deploys OptimismSuperchainERC20 Beacon Proxies
+///         using CREATE3.
+contract OptimismSuperchainERC20Factory is IOptimismERC20Factory, ISemver {
+    /// @notice Mapping of the deployed OptimismSuperchainERC20 to the remote token address.
+    ///         This is used to keep track of the token deployments.
+    mapping(address superchainToken => address remoteToken) public deployments;
+
+    /// @notice Emitted when an OptimismSuperchainERC20 is deployed.
+    /// @param superchainToken  Address of the SuperchainERC20 deployment.
+    /// @param remoteToken      Address of the corresponding token on the remote chain.
+    /// @param deployer         Address of the account that deployed the token.
+    event OptimismSuperchainERC20Created(
+        address indexed superchainToken, address indexed remoteToken, address deployer
+    );
+
+    /// @notice Semantic version.
+    /// @custom:semver 1.0.0-beta.1
+    string public constant version = "1.0.0-beta.1";
+
+    /// @notice Deploys a OptimismSuperchainERC20 Beacon Proxy using CREATE3.
+    /// @param _remoteToken      Address of the remote token.
+    /// @param _name             Name of the OptimismSuperchainERC20.
+    /// @param _symbol           Symbol of the OptimismSuperchainERC20.
+    /// @param _decimals         Decimals of the OptimismSuperchainERC20.
+    /// @return _superchainERC20 Address of the OptimismSuperchainERC20 deployment.
+    function deploy(
+        address _remoteToken,
+        string memory _name,
+        string memory _symbol,
+        uint8 _decimals
+    )
+        external
+        returns (address _superchainERC20)
+    {
+        bytes memory initCallData =
+            abi.encodeCall(OptimismSuperchainERC20.initialize, (_remoteToken, _name, _symbol, _decimals));
+
+        bytes memory creationCode = bytes.concat(
+            type(BeaconProxy).creationCode, abi.encode(Predeploys.OPTIMISM_SUPERCHAIN_ERC20_BEACON, initCallData)
+        );
+
+        bytes32 salt = keccak256(abi.encode(_remoteToken, _name, _symbol, _decimals));
+        _superchainERC20 = CREATE3.deploy({ salt: salt, creationCode: creationCode, value: 0 });
+
+        deployments[_superchainERC20] = _remoteToken;
+
+        emit OptimismSuperchainERC20Created(_superchainERC20, _remoteToken, msg.sender);
+    }
+}

packages/contracts-bedrock/src/libraries/Predeploys.sol

@@ -95,10 +95,16 @@ library Predeploys {
     /// @notice Address of the ETHLiquidity predeploy.
     address internal constant ETH_LIQUIDITY = 0x4200000000000000000000000000000000000025;
 
-    /// TODO: Add correct predeploy address for OptimismSuperchainERC20Factory
     /// @notice Address of the OptimismSuperchainERC20Factory predeploy.
     address internal constant OPTIMISM_SUPERCHAIN_ERC20_FACTORY = 0x4200000000000000000000000000000000000026;
 
+    /// @notice Address of the OptimismSuperchainERC20Beacon predeploy.
+    address internal constant OPTIMISM_SUPERCHAIN_ERC20_BEACON = 0x4200000000000000000000000000000000000027;
+
+    // TODO: Precalculate the address of the implementation contract
+    /// @notice Arbitrary address of the OptimismSuperchainERC20 implementation contract.
+    address internal constant OPTIMISM_SUPERCHAIN_ERC20 = 0xB9415c6cA93bdC545D4c5177512FCC22EFa38F28;
+
     /// @notice Returns the name of the predeploy at the given address.
     function getName(address _addr) internal pure returns (string memory out_) {
         require(isPredeployNamespace(_addr), "Predeploys: address must be a predeploy");
@@ -128,12 +134,13 @@ library Predeploys {
         if (_addr == SUPERCHAIN_WETH) return "SuperchainWETH";
         if (_addr == ETH_LIQUIDITY) return "ETHLiquidity";
         if (_addr == OPTIMISM_SUPERCHAIN_ERC20_FACTORY) return "OptimismSuperchainERC20Factory";
+        if (_addr == OPTIMISM_SUPERCHAIN_ERC20_BEACON) return "OptimismSuperchainERC20Beacon";
         revert("Predeploys: unnamed predeploy");
     }
 
     /// @notice Returns true if the predeploy is not proxied.
     function notProxied(address _addr) internal pure returns (bool) {
-        return _addr == GOVERNANCE_TOKEN || _addr == WETH;
+        return _addr == GOVERNANCE_TOKEN || _addr == WETH || _addr == OPTIMISM_SUPERCHAIN_ERC20_BEACON;
     }
 
     /// @notice Returns true if the address is a defined predeploy that is embedded into new OP-Stack chains.
@@ -146,7 +153,8 @@ library Predeploys {
             || _addr == L1_FEE_VAULT || _addr == SCHEMA_REGISTRY || _addr == EAS || _addr == GOVERNANCE_TOKEN
             || (_useInterop && _addr == CROSS_L2_INBOX) || (_useInterop && _addr == L2_TO_L2_CROSS_DOMAIN_MESSENGER)
             || (_useInterop && _addr == SUPERCHAIN_WETH) || (_useInterop && _addr == ETH_LIQUIDITY)
-            || (_useInterop && _addr == OPTIMISM_SUPERCHAIN_ERC20_FACTORY);
+            || (_useInterop && _addr == OPTIMISM_SUPERCHAIN_ERC20_FACTORY)
+            || (_useInterop && _addr == OPTIMISM_SUPERCHAIN_ERC20_BEACON);
     }
 
     function isPredeployNamespace(address _addr) internal pure returns (bool) {