Add nix flake support

.gitignore

@@ -18,3 +18,6 @@
 /tests/**/output
 
 src/Server/Generated.idr
+
+#nix build output
+/result

README.md

@@ -8,6 +8,25 @@ Language Server for Idris2.
 pack install-app lsp
 ```
 
+## Installation with Nix Flakes
+```bash
+nix profile install github:idris-community/idris2-lsp
+```
+
+Alternatively, add `idris2-lsp` to your `devShell`:
+```nix
+devShell = npkgs.mkShell {
+  buildInputs = [ ... idris2-lsp.defaultPackages.${system} ];
+  # ...
+}
+```
+
+and idris2-lsp will be available in your development shell
+```bash
+nix develop
+code # will connect to idris2-lsp
+```
+
 ## Manual Installation
 ```bash
 # If you already have idris2, uninstall idris2 unless you installed it from source

default.nix

@@ -0,0 +1,4 @@
+(import (fetchTarball
+  "https://github.com/edolstra/flake-compat/archive/master.tar.gz") {
+    src = builtins.fetchGit ./.;
+  }).defaultNix

flake.nix

@@ -0,0 +1,85 @@
+{
+  description = "Idris 2 Language Server";
+
+  inputs.flake-utils.url = "github:numtide/flake-utils";
+  inputs.idris = {
+    url = "github:idris-lang/Idris2";
+    inputs.nixpkgs.follows = "nixpkgs";
+    inputs.flake-utils.follows = "flake-utils";
+  };
+
+  outputs = { self, nixpkgs, idris, flake-utils }:
+    flake-utils.lib.eachDefaultSystem (system:
+      let
+        npkgs = import nixpkgs { inherit system; };
+        idrisPkgs = idris.packages.${system};
+        buildIdris = idris.buildIdris.${system};
+
+        #from https://github.com/claymager/idris2-pkgs/blob/main/packageSet.nix
+        #should probably be upstreamed to Idris
+        idris2-api = buildIdris {
+          projectName = "idris2api";
+          src = idris;
+          idrisLibraries = [ ];
+          buildInputs = [ npkgs.gmp ];
+          postConfigure = 
+          ''
+          LONG_VERSION=$(idris2 --version)
+          ARR=($(echo $LONG_VERSION | sed 's/-/ /g; s/\./,/g' ))
+          VERSION="((''${ARR[-2]}), \"${idris.shortRev or "dirty"}\")"
+
+          echo "-- @""generated" > src/IdrisPaths.idr
+          echo 'module IdrisPaths' >> src/IdrisPaths.idr
+          echo "export idrisVersion : ((Nat,Nat,Nat), String); idrisVersion = $VERSION" >> src/IdrisPaths.idr
+          echo 'export yprefix : String; yprefix="~/.idris2"' >> src/IdrisPaths.idr
+          '';
+        };
+
+
+        contrib = buildIdris {
+          projectName = "contrib";
+          src = idris + "/libs/contrib";
+          idrisLibraries = [ ];
+        };
+        idris2-prelude = buildIdris {
+          projectName = "prelude";
+          src = idris + "/libs/prelude";
+          idrisLibraries = [ ];
+        };
+        idris2-base = buildIdris {
+          projectName = "base";
+          src = idris + "/libs/base";
+          idrisLibraries = [ ];
+        };
+
+        # libs that are needed at runtime
+        # something like this should also probably be upstreamed to Idris
+        runtimeLibs = [ idris2-prelude.installLibrary idris2-base.installLibrary ];
+
+        lib-dirs =
+        let 
+          idrName = "idris2-${idris.version}";
+          libSuffix = "lib/${idrName}";
+        in
+          nixpkgs.lib.strings.concatMapStringsSep ":" (p: "${p}/${libSuffix}") runtimeLibs;
+
+        pkgs = buildIdris {
+          projectName = "lsp";
+          src = ./.;
+          idrisLibraries = [ contrib.installLibrary idris2-api.installLibrary ];
+          buildInputs = runtimeLibs ++ [ npkgs.makeWrapper ];
+          postInstall = ''
+          wrapProgram $out/bin/idris2-lsp --prefix IDRIS2_PACKAGE_PATH : ${lib-dirs}
+          '';
+        };
+      in rec {
+        packages = pkgs // idrisPkgs;
+        defaultPackage = pkgs.build;
+        devShell = npkgs.mkShell {
+          buildInputs = [ idrisPkgs.idris2 npkgs.rlwrap ];
+          shellHook = ''
+            alias idris2="rlwrap -s 1000 idris2 --no-banner"
+          '';
+        };
+      });
+}